msqueue.vbs - vbscript script by ActiveXperts Software
msqueue.vbs checks MS Queue length on a host computer.
Use msqueue.vbs directly from ActiveXperts Network Monitor; in the Manager's 'Monitor' menu, select 'New Check (Script)' and select msqueue.vbs. Configure the required parameter, or press 'Load a working sample'.
In ActiveXperts Network Monitor, Administrators can use three different scripting languages: Powershell, VBScript and SSH.
msqueue.vbs script code
' ///////////////////////////////////////////////////////////////////////////////
' // ActiveXperts Network Monitor - VBScript based checks
' // For more information about ActiveXperts Network Monitor and VBScript, visit
' // http://www.activexperts.com/support/network-monitor/online/vbscript/
' ///////////////////////////////////////////////////////////////////////////////
Option Explicit
' Declaration of global variables
Dim SYSDATA, SYSEXPLANATION ' SYSDATA is displayed in the 'Data' column in the Manager; SYSEXPLANATION in the 'LastResponse' column
' Constants - return values
Const retvalUnknown = 1 ' ActiveXperts Network Monitor functions should always return True (-1, Success), False (0, Error) or retvalUnknown (1, Uncertain)
' // To test a function outside Network Monitor (e.g. using CSCRIPT from the
' // command line), remove the comment character (') in the following lines:
' Dim bResult
' bResult = CheckQueueLength( "localhost", "", "private$\admin_queue$", 10 )
' WScript.Echo "Return value: [" & bResult & "]"
' WScript.Echo "SYSDATA: [" & SYSDATA & "]"
' WScript.Echo "SYSEXPLANATION: [" & SYSEXPLANATION & "]"
' //////////////////////////////////////////////////////////////////////////////
Function CheckQueueLength( strHost, strAltCredentials, strQueue, nMaxLength )
' Description:
' Checks Ms Queue length on a (remote) computer.
' Parameters:
' 1) strHost As String - Hostname or IP address of the computer you want to monitor
' 2) strAltCredentials As String - Specify an empty string to use Network Monitor service credentials.
' To use alternate credentials, enter a server that is defined in Server Credentials table.
' (To define Server Credentials, choose Tools->Options->Server Credentials)
' 3) strQueue As String - Queue that you want to monitor. Syntax: private$\queuename
' 4) nMaxLength As Number - Maximum allowed items in queue
' Usage:
' CheckQueueLength( "<Hostname | IP>", "<Empty String | Server>", "<Queue Name>", <Max_Queue_Length> )
' Sample:
' CheckQueueLength( "localhost", "", "private$\admin_queue$", 10 )
Dim strAltLogin, strAltPassword, objWMIService
CheckQueueLength = retvalUnknown ' Default return value
SYSDATA = "" ' Will hold the actual CPU percentage value when the function returns
SYSEXPLANATION = "" ' Set initial value
strAltLogin = ""
strAltPassword = ""
' If alternate credentials are specified, retrieve the alternate login and password from the ActiveXperts global settings
If( strAltCredentials <> "" ) Then
If( Not getCredentials( strHost, strAltCredentials, strAltLogin, strAltPassword, SYSEXPLANATION )) Then
Exit Function
End If
End If
' WMI Connect
If( Not wmiConnect( strHost, strAltLogin, strAltPassword, objWMIService, SYSEXPLANATION ) ) Then
Exit Function
End If
CheckQueueLength = checkQueueLengthWMI( objWMIService, strHost, strQueue, nMaxLength, SYSDATA, SYSEXPLANATION )
End Function
' //////////////////////////////////////////////////////////////////////////////
' // --- Private Functions section ---
' // Private functions names should start with a lower case character, so they
' // will not be listed in the Network Monitor's function browser.
' //////////////////////////////////////////////////////////////////////////////
Function checkQueueLengthWMI( objWMIService, strHost, strQueue, nMaxLength, BYREF strSysData, BYREF strSysExplanation )
Dim objQueue, collQueues, nQueueLength, nQueueBytes, nPos, strQueueName
checkQueueLengthWMI = retvalUnknown ' Default return value
On Error Resume Next
Set collQueues = objWMIService.ExecQuery( "select * from Win32_PerfRawData_MSMQ_MSMQQueue" )
If( Err.Number <> 0 ) Then
strSysData = ""
strSysExplanation = "Unable to query Win32_PerfRawData_MSMQ_MSMQQueue on computer [" & strHost & "]"
Exit Function
End If
If( collQueues.Count <= 0 ) Then
strSysData = ""
strSysExplanation = "Win32_PerfRawData_MSMQ_MSMQQueue class does not exist on computer [" & strHost & "]"
Exit Function
End If
On Error Goto 0
For Each objQueue in collQueues
If( Err.Number <> 0 ) Then
checkQueueLengthWMI= retvalUnknown
strSysExplanation = "Unable to list queues on computer [" & strHost & "]"
Exit Function
End If
' NOTE: objQueue.Name is formatted like this: Server01\Private$\AdminQueue$
' However, we cannot use Server01 because hte user may have specified localhost, or 192.168.1.1 as computername
' So now, filter the queuename by stripping the
nPos = Instr( objQueue.Name, "\" )
strQueueName = Mid( objQueue.Name, nPos + 1 )
If( UCase( strQueueName ) = UCase( strQueue ) ) Then
nQueueLength = objQueue.MessagesInQueue
nQueueBytes = objQueue.BytesInQueue
strSysData = nQueueLength
strSysExplanation = "Queue length=[" & nQueueLength & "], maximum allowed=[" & nMaxLength & "]"
If( nQueueLength > nMaxLength ) Then
checkQueueLengthWMI = False
Else
checkQueueLengthWMI = True
End If
Exit Function
End If
Next
checkQueueLengthWMI = False
strSysExplanation = "Queue [" & strQueue & "] is not found on computer [" & strHost & "]"
End Function
' //////////////////////////////////////////////////////////////////////////////
Function getCredentials( strHost, strAltCredentials, BYREF strAltLogin, BYREF strAltPassword, BYREF strSysExplanation )
Dim objNMServerCredentials
strAltLogin = ""
strAltPassword = ""
strSysExplanation = ""
getCredentials = False
If( strAltCredentials = "" ) Then
' No alternate credentials specified, so login and password are empty and service credentials will be used
getCredentials = True
Exit Function
End If
Set objNMServerCredentials = CreateObject( "ActiveXperts.NMServerCredentials" )
strAltLogin = objNMServerCredentials.GetLogin( strAltCredentials )
strAltPassword = objNMServerCredentials.GetPassword( strAltCredentials )
If( strAltLogin = "" ) Then
getCredentials = False
strSysExplanation = "No alternate credentials defined for [" & strAltCredentials & "]. In the Manager application, select 'Options' from the 'Tools' menu and select the 'Server Credentials' tab to enter alternate credentials"
Exit Function
End If
getCredentials = True
End Function
' //////////////////////////////////////////////////////////////////////////////
Function wmiConnect( strHost, strAltLogin, strAltPassword, BYREF objWMIService, BYREF strSysExplanation )
Dim objSWbemLocator, colItems
Dim bConnectResult
wmiConnect = False
Set objWMIService = Nothing
If( strAltLogin = "" ) Then
' Connect to remote host on same domain using same security context
On Error Resume Next
Set objWMIService = GetObject( "winmgmts:{impersonationLevel=Impersonate}!\\" & strHost &"\root\cimv2" )
If( Err.Number <> 0 ) Then
bConnectResult = False
Else
bConnectResult = True
End If
On Error Goto 0
Else
' Connect to remote host using different security context and/or different domain
On Error Resume Next
Set objSWbemLocator = CreateObject( "WbemScripting.SWbemLocator" )
Set objWMIService = objSWbemLocator.ConnectServer( strHost, "root\cimv2", strAltLogin, strAltPassword )
If( Err.Number <> 0 ) Then
bConnectResult = False
Else
bConnectResult = True
End If
objWMIService.Security_.ImpersonationLevel = 3
On Error Goto 0
End If
If( Not bConnectResult ) Then
Set objWMIService = Nothing
wmiConnect = False
strSysExplanation = "Unable to connect to [" & strHost & "]. Possible reasons: no WMI installed on the remote server, firewall blocking WMI calls, login failure, or remote server down"
Exit Function
End If
wmiConnect = True
End Function