contact@activexperts.com +31748507807

ActiveXperts.com » Network Component » How to Use Network Component » RSH » VBScript

How to use RSH in VBScript

Network Component provides an easy-to-use development interface to a variety of IP protocols. By using Network Component, you can very easily create or enhance applications with network features.

Network Component features the following: DNS, FTP, HTTP, HTTPs, ICMP Ping, IP-to-Country, MSN, NTP, RSH, SCP, SFTP, SNMP v1/v2c (Get, GetNext, Set), SNMP Traps, SNMP MIB, SSH, TCP, Telnet, TFTP, UDP, Telnet, Wake-On-LAN and more.

Network Component can be well integrated into any development platform that supports ActiveX objects.

Step 1: Download and install the Network Component

Download Network Component from the ActiveXperts Download Site and start the installation. The installation guides you through the installation process.

Step 2: Create a new script

Create a new script using your favorite editor. You can simply use notepad. However, a VBScript editor is recommended, so you can browse through objects, objects properties and object functions.

You're now able to write a more advanced script to communicate using the Network Component.

Step 3: Create the Network Component object in VBScript

Create a new VBScript file called DEMO.VBS. It is recommended to insert the following line on top of your code: 

Option Explicit

This statement requires that all variable names be defined (with the Dim statement), to avoid simple typos that can cause incredible headaches and long debugging sessions for something that should have never happened.

Now, declare the Network Component object(s):

Dim objRsh

Create the Network Component object(s) like this:

Set objRsh      = CreateObject( "AxNetwork.Rsh" )

Now, add the following lines to the file to have your first Network Component VBScript program:

WScript.Echo "Version: " & objRsh.Version
WScript.Echo "License Status: " & objRsh.LicenseStatus

Appendix: Full source code

  
' ********************************************************************
' ActiveXperts Network Component sample - Rsh Remote Shell
'   This RSH sample run the 'ls' command on a (remote) server
'   using the 'root' user.
' Written by ActiveXperts Software 
'   https://www.activexperts.com
' ********************************************************************

Option Explicit

' Declare variables
Dim objRsh, fso

' Create a RSh instance
Set objRsh = CreateObject( "AxNetwork.RSh" )

' A license key is required to unlock this component after the trial period has expired.
' Call 'Activate' with a valid license key as its first parameter. Second parameter determines whether to save the license key permanently 
' to the registry (True, so you need to call Activate only once), or not to store the key permanently (False, so you need to call Activate
' every time the component is created). For details, see manual, chapter "Product Activation".
'
' objRsh.Activate "XXXXX-XXXXX-XXXXX", False

' Component info
Wscript.Echo "ActiveXpert Network Component " & objRsh.Version
Wscript.Echo "Build: " & objRsh.Build & vbCrLf & "Module: " & objRsh.Module
Wscript.Echo "License Status: " & objRsh.LicenseStatus & vbCrLf & "License Key: " & objRsh.LicenseKey & vbCrLf

' Set Logfile
Set fso = CreateObject( "Scripting.FileSystemObject" )
objRsh.LogFile = fso.GetSpecialFolder(2) & "\Rsh.log"
WScript.Echo "Log file: " & objRsh.LogFile & vbCrLf

objRsh.Host     = ReadInput( "Enter name or IP address of the (remote) RSH machine:", "localhost", False )
objRsh.UserName = ReadInput( "Enter user name to logon to remote machine:", "root", False )

objRsh.Command  = ReadInput( "Enter command:", "ls", False )
objRsh.ScriptTimeOut = 5000
objRsh.Run
WScript.Echo "Run, result: " & objRsh.LastError & " (" & objRsh.GetErrorDescription( objRsh.LastError ) & ")"

If objRsh.LastError = 0 Then
   WScript.Echo "StdOut: " & objRsh.StdOut
   WScript.Echo "StdErr: " & objRsh.StdErr
End If

WScript.Echo "Ready."


' ***************************************************************************
' Function ReadInput
' ***************************************************************************
Function ReadInput( ByVal strTitle, ByVal strDefault, ByVal bAllowEmpty )

   Dim strInput, strReturn
   
   Do
      strInput = inputbox( strTitle, "Enter value", strDefault )
      If ( strInput <> "" ) Then
         strReturn = strInput
      End If
   Loop until strReturn <> "" Or bAllowEmpty
   
   ReadInput = strReturn
End Function

You can download the complete samples here. There are many other working Network Component scripts on our site and shipped with the product.

M