Contact Info

Crumbtrail

ActiveXperts.com » Network Component » How to Use Network Component » ICMP Ping » VBScript

How to use ICMP in VBScript

Network Component provides an easy-to-use development interface to a variety of IP protocols. By using Network Component, you can very easily create or enhance applications with network features.

Network Component features the following: DNS, FTP, HTTP, HTTPs, ICMP Ping, IP-to-Country, MSN, NTP, RSH, SCP, SFTP, SNMP v1/v2c (Get, GetNext, Set), SNMP Traps, SNMP MIB, SSH, TCP, Telnet, TFTP, UDP, Telnet, Wake-On-LAN and more.

Network Component can be well integrated into any development platform that supports ActiveX objects.



Step 1: Download and install the Network Component

Download Network Component from the ActiveXperts Download Site and start the installation. The installation guides you through the installation process.

Step 2: Create a new script

Create a new script using your favorite editor. You can simply use notepad. However, a VBScript editor is recommended, so you can browse through objects, objects properties and object functions.

You're now able to write a more advanced script to communicate using the Network Component.

Step 3: Create the Network Component object in VBScript

Create a new VBScript file called DEMO.VBS. It is recommended to insert the following line on top of your code:

Option Explicit

This statement requires that all variable names be defined (with the Dim statement), to avoid simple typos that can cause incredible headaches and long debugging sessions for something that should have never happened.

Now, declare the Network Component object(s):

Dim objIcmp

Create the Network Component object(s) like this:

Set objIcmp      = CreateObject( "AxNetwork.Icmp" )

Now, add the following lines to the file to have your first Network Component VBScript program:

WScript.Echo "Version: " & objIcmp.Version
WScript.Echo "License Status: " & objIcmp.LicenseStatus

Appendix: Full source code

' ********************************************************************
' ActiveXperts Network Component sample - ICMP
'  ICMP Sample: Ping a host and show the response time
' Written by ActiveXperts Software 
'   https://www.activexperts.com
' ********************************************************************

Option Explicit

Dim objICmp, i, strHost, fso

' Create a socket instance
Set objIcmp = CreateObject( "AxNetwork.Icmp")

' A license key is required to unlock this component after the trial period has expired.
' Call 'Activate' with a valid license key as its first parameter. Second parameter determines whether to save the license key permanently 
' to the registry (True, so you need to call Activate only once), or not to store the key permanently (False, so you need to call Activate
' every time the component is created). For details, see manual, chapter "Product Activation".
'
' objIcmp.Activate "XXXXX-XXXXX-XXXXX", False

' Component info
Wscript.Echo "ActiveXpert Network Component " & objIcmp.Version
Wscript.Echo "Build: " & objIcmp.Build & vbCrLf & "Module: " & objIcmp.Module
Wscript.Echo "License Status: " & objIcmp.LicenseStatus & vbCrLf & "License Key: " & objIcmp.LicenseKey & vbCrLf

' Set Logfile
Set fso = CreateObject( "Scripting.FileSystemObject" )
objIcmp.LogFile = fso.GetSpecialFolder(2) & "\Http.log"
WScript.Echo "Log file: " & objIcmp.LogFile & vbCrLf

strHost         = ReadInput( "Enter a hostname or IP address", "www.activexperts.com", False ) 

For i = 1 to 4
   objIcmp.Ping strHost, 2000 ' Timeout 2000 ms
   If( objIcmp.LastError = 0 ) Then
     WScript.Echo "Reply from " & strHost & ": time=" & objIcmp.LastDuration & "ms TTL=" & objIcmp.LastTtl 
   Else
     WScript.Echo "Error " & objIcmp.LastError & ": " & objIcmp.GetErrorDescription( objIcmp.LastError )
   End If
   objIcmp.Sleep 1000
Next

WScript.Echo "Ready."


' ***************************************************************************
' Function ReadInput
' ***************************************************************************
Function ReadInput( ByVal strTitle, ByVal strDefault, ByVal bAllowEmpty )

   Dim strInput, strReturn
   
   Do
      strInput = inputbox( strTitle, "Enter value", strDefault )
      If ( strInput <> "" ) Then
         strReturn = strInput
      End If
   Loop until strReturn <> "" Or bAllowEmpty
   
   ReadInput = strReturn
End Function


You can download the complete sample on our FTP site ftp.activexperts-lab.com/samples/network-component/. There are many other working Network Component scripts on our site and shipped with the product.