MsIsaServer.vbs - Microsoft ISA Server monitoring using ActiveXperts Network Monitor
ActiveXperts Network Monitor ships with a powerful set of pre-defined checks. Each individual check has a static number of configuration items. To monitor other items, or to combine monitoring items, you can make use of custom VBScript checks.
Most of the built-in checks have a VBScript equivalent, implemented as a Function in a VBScript (.vbs) file. Out-of-the-box, each VBScript function monitors the same items as the built-in check. Feel free to modify a function. The VBScript check can be customized by editing the VBScript function.
To add a new VBScript-based Microsoft ISA Server monitoring check, do the following:
- On the 'Monitor menu', click 'New Monitoring Check (VBScript)'. The 'VBScript Check' dialog box appears;
- In the 'File selection box', select 'MsIsaServer.vbs';
- In the 'Function selection box', select 'CheckIsaServer';
- In the 'Function parameters group box' enter the required parameters. You can also load a working sample first by clicking on the 'Load a sample, click here' link.
To customize the above monitoring check, click on the 'Edit button' next to the 'File selection box'. Notepad will be launched. You can now make changes to the VBScript function(s).
MsIsaServer.vbs script source code
' ///////////////////////////////////////////////////////////////////////////////
' // ActiveXperts Network Monitor - VBScript based checks
' // © ActiveXperts Software B.V.
' //
' // For more information about ActiveXperts Network Monitor and VBScript, please
' // visit the online ActiveXperts Network Monitor VBScript Guidelines at:
' // https://www.activexperts.com/support/network-monitor/online/vbscript/
' //
' ///////////////////////////////////////////////////////////////////////////////
' /
Option Explicit
Const retvalUnknown = 1
Dim SYSDATA, SYSEXPLANATION ' Used by Network Monitor, don't change the names
' ///////////////////////////////////////////////////////////////////////////////
' // To test a function outside Network Monitor (e.g. using CSCRIPT from the
' // command line), remove the comment character (') in the following 5 lines:
' Dim bResult
' bResult = CheckIsaServer( "localhost", "", "cf", 2004 )
' WScript.Echo "Return value: [" & bResult & "]"
' WScript.Echo "SYSDATA: [" & SYSDATA & "]"
' WScript.Echo "SYSEXPLANATION: [" & SYSEXPLANATION & "]"
' //////////////////////////////////////////////////////////////////////////////
' //////////////////////////////////////////////////////////////////////////////
Function CheckIsaServer( strComputer, strCredentials, strMode, numVersion )
' Description:
' Checks if ISA Server is running; it checks the ISA services
' Parameters:
' 1) strComputer As String - Hostname or IP address of the ISA server you want to check
' 2) strCredentials As String - Specify an empty string to use Network Monitor service credentials.
' To use alternate credentials, enter a server that is defined in Server Credentials table.
' (To define Server Credentials, choose Tools->Options->Server Credentials)
' 3) strMode As String - Include a 'c' for caching mode and/or an 'f' for firewall mode
' 4) numVersion As Number - ISA Server version (either 2006, 2004 or 2000)
' Usage:
' CheckIsaServer( "", "", "", )
' Sample:
' CheckIsaServer( "localhost", "", "cf", 2004 )
Dim objWMIService, numResult
CheckIsaServer = retvalUnknown ' Default return value
SYSDATA = "" ' Not used by this function
SYSEXPLANATION = "" ' Set initial value
If( Not getWMIObject( strComputer, strCredentials, objWMIService, SYSEXPLANATION ) ) Then
Exit Function
End If
CheckIsaServer = checkIsaServerWMI( objWMIService, strComputer, strMode, numVersion, SYSEXPLANATION )
End Function
' //////////////////////////////////////////////////////////////////////////////
' //
' // Private Functions
' // NOTE: Private functions are used by the above functions, and will not
' // be called directly by the ActiveXperts Network Monitor Service.
' // Private function names start with a lower case character and will
' // not be listed in the Network Monitor's function browser.
' //
' //////////////////////////////////////////////////////////////////////////////
Function checkIsaServerWMI( objWMIService, strComputer, strMode, numVersion, BYREF strSysExplanation )
Dim lstServices, numResult
checkIsaServerWMI = retvalUnknown ' Default return value
strSysExplanation = "Unable to check the ISA server machine"
If( numVersion <> 2006 AND numVersion <> 2004 AND numVersion <> 2000 ) Then
checkIsaServerWMI = retvalUnknown
strSysExplanation = "Cannot check this version of MS ISA Server"
Exit Function
End If
' Get the services list
If( Not retrieveServicesList( objWMIService, strComputer, lstServices, strSysExplanation ) ) Then
Exit Function
End If
If( numVersion = 2006 ) Then
numResult = checkIsaServer2006Services( lstServices, strMode, strSysExplanation )
If( numResult <> True ) Then
checkIsaServerWMI = numResult
Exit Function
End If
End If
If( numVersion = 2004 ) Then
numResult = checkIsaServer2004Services( lstServices, strMode, strSysExplanation )
If( numResult <> True ) Then
checkIsaServerWMI = numResult
Exit Function
End If
End If
If( numVersion = 2000 ) Then
numResult = checkIsaServer2000Services( lstServices, strMode, strSysExplanation )
If( numResult <> True ) Then
checkIsaServerWMI = numResult
Exit Function
End If
End If
checkIsaServerWMI = True
strSysExplanation = "All conditions are met"
End Function
' //////////////////////////////////////////////////////////////////////////////
Function checkIsaServer2006Services( objServices, strMode, BYREF strSysExplanation )
' Check if the ISA 2006 Services are in the specified list
Dim result
result = isServiceRunning( objServices, "isactrl", "Microsoft ISA Server Control", strSysExplanation )
If( result = True AND ( InStr( strMode, "f" ) <> 0 OR InStr( strMode, "F" ) <> 0 ) ) Then
result = isServiceRunning( objServices, "fwsrv", "Microsoft Firewall", strSysExplanation )
End If
If( result = True ) Then
result = isServiceRunning( objServices, "isastg", "Microsoft ISA Server Storage", strSysExplanation )
End If
If( result = True ) Then
result = isServiceRunning( objServices, "isasched", "Microsoft ISA Server Job Scheduler", strSysExplanation )
End If
checkIsaServer2006Services = result
End Function
' //////////////////////////////////////////////////////////////////////////////
Function checkIsaServer2004Services( objServices, strMode, BYREF strSysExplanation )
' Check if the ISA 2004 Services are in the specified list
Dim result
result = isServiceRunning( objServices, "isactrl", "Microsoft ISA Server Control", strSysExplanation )
If( result = True AND ( InStr( strMode, "f" ) <> 0 OR InStr( strMode, "F" ) <> 0 ) ) Then
result = isServiceRunning( objServices, "fwsrv", "Microsoft Firewall", strSysExplanation )
End If
If( result = True ) Then
result = isServiceRunning( objServices, "isastg", "Microsoft ISA Server Storage", strSysExplanation )
End If
If( result = True ) Then
result = isServiceRunning( objServices, "isasched", "Microsoft ISA Server Job Scheduler", strSysExplanation )
End If
checkIsaServer2004Services = result
End Function
' //////////////////////////////////////////////////////////////////////////////
Function checkIsaServer2000Services( objServices, strMode, BYREF strSysExplanation )
' Check if the ISA 2000 Services are in the specified list
Dim result
result = isServiceRunning( objServices, "isactrl", "Microsoft ISA Server Control", strSysExplanation )
If( result = True AND ( InStr( strMode, "f" ) <> 0 OR InStr( strMode, "F" ) <> 0 ) ) Then
result = isServiceRunning( objServices, "fwsrv", "Microsoft Firewall", strSysExplanation )
End If
If( result = True ) Then
result = isServiceRunning( objServices, "w3proxy", "Microsoft Web Proxy", strSysExplanation )
End If
If( result = True ) Then
result = isServiceRunning( objServices, "w3schdwn", "Microsoft Scheduled Cache Content Download", strSysExplanation )
End If
' If( result = True ) Then
' result = isServiceRunning( objServices, "gksvc", "Microsoft Gatekeeper", strSysExplanation )
' End If
checkIsaServer2000Services = result
End Function
' //////////////////////////////////////////////////////////////////////////////
Function retrieveServicesList( objWMIService, strComputer, BYREF lstServices, BYREF strSysExplanation )
' Retrieve the list of running services
retrieveServicesList = False
Set lstServices = Nothing
Set lstServices = objWMIService.ExecQuery( "Select * from Win32_Service WHERE state = ""Running""" )
If( Err.Number <> 0 ) Then
strSysExplanation = "Unable to query WMI on computer [" & strComputer & "]"
Exit Function
End If
If( lstServices.Count <= 0 ) Then
strSysExplanation = "Win32_Service class does not exist on computer [" & strComputer & "]"
Exit Function
End If
On Error Goto 0
retrieveServicesList = True
End Function
' //////////////////////////////////////////////////////////////////////////////
Function isServiceRunning( BYREF lstServices, strServiceName, strServiceDescription, BYREF strSysExplanation )
' Check if a given service exists as running service in the services list
Dim objService
isServiceRunning = False ' Default return value
For Each objService in lstServices
If( Err.Number <> 0 ) Then
isServiceRunning = retvalUnknown
strSysExplanation = "Unable to list services"
Exit Function
End If
' Check If this is the service we are looking for
If( LCase( objService.Name ) = LCase( strServiceName ) ) Then
isServiceRunning = True
Exit Function
End If
Next
' The service was not found, show an error message
strSysExplanation = "'" & strServiceDescription & "' service is not running"
isServiceRunning = False
End Function
' //////////////////////////////////////////////////////////////////////////////
Function getWMIObject( strComputer, strCredentials, BYREF objWMIService, BYREF strSysExplanation )
On Error Resume Next
Dim objNMServerCredentials, objSWbemLocator, colItems
Dim strUsername, strPassword
getWMIObject = False
Set objWMIService = Nothing
If( strCredentials = "" ) Then
' Connect to remote host on same domain using same security context
Set objWMIService = GetObject( "winmgmts:{impersonationLevel=Impersonate}!\\" & strComputer &"\root\cimv2" )
Else
Set objNMServerCredentials = CreateObject( "ActiveXperts.NMServerCredentials" )
strUsername = objNMServerCredentials.GetLogin( strCredentials )
strPassword = objNMServerCredentials.GetPassword( strCredentials )
If( strUsername = "" ) Then
getWMIObject = False
strSysExplanation = "No alternate credentials defined for [" & strCredentials & "]. In the Manager application, select 'Options' from the 'Tools' menu and select the 'Server Credentials' tab to enter alternate credentials"
Exit Function
End If
' Connect to remote host using different security context and/or different domain
Set objSWbemLocator = CreateObject( "WbemScripting.SWbemLocator" )
Set objWMIService = objSWbemLocator.ConnectServer( strComputer, "root\cimv2", strUsername, strPassword )
If( Err.Number <> 0 ) Then
objWMIService = Nothing
getWMIObject = False
strSysExplanation = "Unable to access [" & strComputer & "]. Possible reasons: WMI not running on the remote server, Windows firewall is blocking WMI calls, insufficient rights, or remote server down"
Exit Function
End If
objWMIService.Security_.ImpersonationLevel = 3
End If
If( Err.Number <> 0 ) Then
objWMIService = Nothing
getWMIObject = False
strSysExplanation = "Unable to access '" & strComputer & "'. Possible reasons: no WMI installed on the remote server, no rights to access remote WMI service, or remote server down"
Exit Function
End If
getWMIObject = True
End Function