Http.vbs - Monitor HTTP(s) web sites using ActiveXperts Network Monitor

ActiveXperts Network Monitor ships with a powerful set of pre-defined checks. Each individual check has a static number of configuration items. To monitor other items, or to combine monitoring items, you can make use of custom VBScript checks.

Most of the built-in checks have a VBScript equivalent, implemented as a Function in a VBScript (.vbs) file. Out-of-the-box, each VBScript function monitors the same items as the built-in check. Feel free to modify a function. The VBScript check can be customized by editing the VBScript function.

To add a new VBScript-based HTTP monitoring check, do the following:

• On the 'Monitor menu', click 'New Monitoring Check (VBScript)'. The 'VBScript Check' dialog box appears;
• In the 'File selection box', select 'Http.vbs';
• In the 'Function selection box', select 'CheckWebSite';
• In the 'Function parameters group box' enter the required parameters. You can also load a working sample first by clicking on the 'Load a sample, click here' link.

To customize the above monitoring check, click on the 'Edit button' next to the 'File selection box'. Notepad will be launched. You can now make changes to the VBScript function(s).

Http.vbs script source code

' ///////////////////////////////////////////////////////////////////////////////
' // ActiveXperts Network Monitor  - VBScript based checks
' // (c) ActiveXperts Software B.V.
' //
' // For more information about ActiveXperts Network Monitor and VBScript, please
' // visit the online ActiveXperts Network Monitor VBScript Guidelines at:
' //    https://www.activexperts.com/support/network-monitor/online/vbscript/
' // 
' ///////////////////////////////////////////////////////////////////////////////
'  

Option Explicit
Const  retvalUnknown = 1
Dim    SYSDATA, SYSEXPLANATION  ' Used by Network Monitor, don't change the names


' ///////////////////////////////////////////////////////////////////////////////

' // To test a function outside Network Monitor (e.g. using CSCRIPT from the
' // command line), remove the comment character (') in the following 5 lines:
' Dim bResult
' bResult = CheckWebSite( "www.activexperts.com:80/network-monitor/demopage", "ActiveXperts" )
' WScript.Echo "Return value: [" & bResult & "]"
' WScript.Echo "SYSDATA: [" & SYSDATA & "]"
' WScript.Echo "SYSEXPLANATION: [" & SYSEXPLANATION & "]"

' ////////////////////////////////////////////////////////////////////////////////////////



' //////////////////////////////////////////////////////////////////////////////

Function CheckWebSite( strURL, strPattern )

' Description: 
'     Read data from a web page and search for a predefined pattern. 
'     This function uses the Network Component, an ActiveXperts product.
'     Network Component is automatically licensed when ActiveXperts Network Monitor is purchased
'     For more information about Network Component, see: www.activexperts.com/network-component
' Parameters:
'     1) strURL - URL of the web site, without http or https prefix
'     2) strPattern - Text pattern to search for in the specified site
' Usage:
'     CheckWebSite( "<URL>", "<Text Pattern>" )
' Sample:
'     CheckWebSite( "www.activexperts.com:80/network-monitor/demopage", "ActiveXperts" )

    Dim objHttp, strData

    CheckWebSite        = retvalUnknown  ' Default return value
    SYSDATA             = ""             ' Not used by this function
    SYSEXPLANATION      = ""             ' Set initial value

    Set objHttp = CreateObject("ActiveXperts.Http")

    objHttp.Connect( strUrl )
    If( objHttp.LastError <> 0 ) Then
        CheckWebSite    = False
        SYSEXPLANATION  = "Web site is unavailable"
        Exit Function
    End If

    strData = objHttp.ReadData
    If( objHttp.LastError <> 0 ) Then
        CheckWebSite    = False
        SYSEXPLANATION  = "No response received from remote server"
        objHttp.Disconnect
        Exit Function
    End If

    If( InStr( strData, strPattern ) <> 0 ) Then
        CheckWebSite    = True
        SYSEXPLANATION  = "Web site is available, text pattern found"
    Else
        CheckWebSite    = False
        SYSEXPLANATION  = "Web site is available, text pattern not found"
    End If

    objHttp.Disconnect
End Function