Ftp.vbs - Monitoring FTP using ActiveXperts Network Monitor

ActiveXperts Network Monitor ships with a powerful set of pre-defined checks. Each individual check has a static number of configuration items. To monitor other items, or to combine monitoring items, you can make use of custom VBScript checks.

Most of the built-in checks have a VBScript equivalent, implemented as a Function in a VBScript (.vbs) file. Out-of-the-box, each VBScript function monitors the same items as the built-in check. Feel free to modify a function. The VBScript check can be customized by editing the VBScript function.

To add a new VBScript-based FTP monitoring check, do the following:

• On the 'Monitor menu', click 'New Monitoring Check (VBScript)'. The 'VBScript Check' dialog box appears;
• In the 'File selection box', select 'Ftp.vbs';
• In the 'Function selection box', select 'CheckFtp';
• In the 'Function parameters group box' enter the required parameters. You can also load a working sample first by clicking on the 'Load a sample, click here' link.

To customize the above monitoring check, click on the 'Edit button' next to the 'File selection box'. Notepad will be launched. You can now make changes to the VBScript function(s).

File.vbs script source code

' ///////////////////////////////////////////////////////////////////////////////
' // ActiveXperts Network Monitor  - VBScript based checks
' // (c) ActiveXperts Software B.V.
' //
' // For more information about ActiveXperts Network Monitor and VBScript, please
' // visit the online ActiveXperts Network Monitor VBScript Guidelines at:
' //    https://www.activexperts.com/support/network-monitor/online/vbscript/
' // 
' ///////////////////////////////////////////////////////////////////////////////
'  

Option Explicit
Const  retvalUnknown = 1
Dim    SYSDATA, SYSEXPLANATION  ' Used by Network Monitor, don't change the names


' ///////////////////////////////////////////////////////////////////////////////
' // To test a function outside Network Monitor (e.g. using CSCRIPT from the
' // command line), remove the comment character (') in the following 5 lines:
' Dim bResult
' bResult = CheckFtp( "ftp.activexperts-labs.com", "anonymous", "me@myself.me", "Samples/NetworkMonitor", "NetworkMonitor.txt" )
' WScript.Echo "Return value: [" & bResult & "]"
' WScript.Echo "SYSDATA: [" & SYSDATA & "]"
' WScript.Echo "SYSEXPLANATION: [" & SYSEXPLANATION & "]"
' ////////////////////////////////////////////////////////////////////////////////////////


Function CheckFtp( strHost, strAccount, strPassword, strDir, strFile )
' Description:
'     Login to an FTP server, change the directory and check for file existence.
'     This function uses the Network Component, an ActiveXperts product.
'     Network Component is automatically licensed when ActiveXperts Network Monitor is purchased
'     For more information about Network Component, see: www.activexperts.com/network-component
' Parameters:
'     1) strHost - Host name or IP address of the FTP host
'     2) strAccount - FTP account; use 'anonymous' for anonymous FTP access
'     3) strPassword - FTP password; use an e-mail address for anonymous FTP access
'     4) strDir - The directory where the file should be located
'     4) strFile - The file to check 
' Usage:
'     CheckFtp( "<Host>", "<Account>" , "<Password>", "<Directory>", "<File>"   )
' Sample:
'     CheckFtp( "ftp.activexperts-labs.com", "anonymous", "me@myself.me", "Samples/NetworkMonitor", "NetworkMonitor.txt" )

    Dim objFtpServer, objFtpFile

    CheckFtp            = retvalUnknown  ' Default return value
    SYSDATA             = ""             ' Not used by this function
    SYSEXPLANATION      = ""             ' Set initial value

    Set objFtpServer = CreateObject("ActiveXperts.FtpServer")

    objFtpServer.Connect strHost, strAccount, strPassword
    If( objFtpServer.LastError <> 0 ) Then
        CheckFtp        = False
        SYSEXPLANATION  = "Login failed, error #" & objFtpServer.LastError & ": " & objFtpServer.GetErrorDescription( objFtpServer.LastError )
        Exit Function
    End If

    ' Use binary transfer for GetFile calls
    objFtpServer.BinaryTransfer = True

    ' Change directory
    objFtpServer.ChangeDir strDir
    If( objFtpServer.LastError <> 0 ) Then
        CheckFtp        = False
        SYSEXPLANATION  = "Failed to change directory, error #" & objFtpServer.LastError & ": " & objFtpServer.GetErrorDescription( objFtpServer.LastError )
        Exit Function
    End If


    ' Iterate over all files
    Set objFtpFile = objFtpServer.FindFirstFile()
    While ( objFtpServer.LastError = 0 )

       If( UCase( objFtpFile.Name ) = UCase( strFile ) ) Then
          CheckFtp        = True
          SYSEXPLANATION  = "File [" & strFile & "] found on FTP server [" & strHost & "]"
          objFtpServer.Disconnect

          Exit Function
       End If

       Set objFtpFile = objFtpServer.FindNextFile()
    WEnd

    CheckFtp        = False
    SYSEXPLANATION  = "File [" & strFile & "] not found on FTP server [" & strHost & "]"

    objFtpServer.Disconnect
End Function